iproute2/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   3 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   4
   5 pkgname=iproute2
   6 pkgver=5.15.0
   7 pkgrel=1
   8 pkgdesc='IP Routing Utilities'
   9 arch=('x86_64')
  10 license=('GPL2')
  11 url='https://git.kernel.org/pub/scm/network/iproute2/iproute2.git'
  12 depends=('glibc' 'iptables' 'libelf')
  13 optdepends=('db: userspace arp daemon'
  14             'libcap: tipc'
  15             'linux-atm: ATM support')
  16 provides=('iproute')
  17 backup=('etc/iproute2/ematch_map'
  18         'etc/iproute2/rt_dsfield'
  19         'etc/iproute2/rt_protos'
  20         'etc/iproute2/rt_realms'
  21         'etc/iproute2/rt_scopes'
  22         'etc/iproute2/rt_tables')
  23 makedepends=('linux-atm')
  24 options=('staticlibs')
  25 validpgpkeys=('9F6FC345B05BE7E766B83C8F80A77F6095CDE47E') # Stephen Hemminger
  26 source=("https://www.kernel.org/pub/linux/utils/net/${pkgname}/${pkgname}-${pkgver}.tar."{xz,sign}
  27         '0001-make-iproute2-fhs-compliant.patch')
  28 sha256sums=('38e3e4a5f9a7f5575c015027a10df097c149111eeb739993128e5b2b35b291ff'
  29             'SKIP'
  30             'f60fefe4c17d3b768824bb50ae6416292bcebba06d73452e23f4147b46b827d3')
  31
  32 prepare() {
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34
  35   # set correct fhs structure
  36   patch -Np1 -i "${srcdir}"/0001-make-iproute2-fhs-compliant.patch
  37
  38   # do not treat warnings as errors
  39   sed -i 's/-Werror//' Makefile
  40
  41 }
  42
  43 build() {
  44   cd "${srcdir}/${pkgname}-${pkgver}"
  45
  46   ./configure
  47   make
  48 }
  49
  50 package() {
  51   cd "${srcdir}/${pkgname}-${pkgver}"
  52
  53   make DESTDIR="${pkgdir}" SBINDIR="/usr/bin" install
  54
  55   # libnetlink isn't installed, install it FS#19385
  56   install -Dm0644 include/libnetlink.h "${pkgdir}/usr/include/libnetlink.h"
  57   install -Dm0644 lib/libnetlink.a "${pkgdir}/usr/lib/libnetlink.a"
  58 }
  59