jasper/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgbase=jasper
   5 pkgname=('jasper' 'jasper-doc')
   6 pkgver=2.0.33
   7 pkgrel=1
   8 pkgdesc='Software-based implementation of the codec specified in the emerging JPEG-2000 Part-1 standard'
   9 url='https://www.ece.uvic.ca/~mdadams/jasper/'
  10 arch=('x86_64')
  11 license=('custom:JasPer2.0')
  12 makedepends=('glibc' 'libjpeg' 'freeglut' 'libxmu' 'glu' 'cmake' 'doxygen')
  13 options=('staticlibs')
  14 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/mdadams/jasper/archive/version-${pkgver}.tar.gz
  15         jasper-1.900.1-fix-filename-buffer-overflow.patch)
  16 sha512sums=('ff88c4b55d52803786520e4f0db10f7cb7cd7642694c866ea7859bc79e409590469fc2c63afe522c7f8b0c00062c155c0fe3b83b8928e319173a3ec9fea3e09e'
  17             'b8d798bf75523c5db263783e42c653dd0cb03deee90be32eddf878bb6893cca02abadd94de6a8c737a5b7fe76f7fb245979f010765e6a95fc520b215e3a2a7f0')
  18 b2sums=('29cd29cf1af285f6054a969991674b12c968b42d70970a1a460fe43e25047b56d2b96a614d0723d9def6c09c9c6b1bdb04289bdcd8cf348449271e5c975074db'
  19         '9b1927a437ed9b32491f07a210600b5a7d10711ec954dadc030a8238b67e9c6d1a8e67956fd7a5515e7060f0a1651fa86763e21d6d20592f8f00e9d3260722a1')
  20
  21 prepare() {
  22   cd ${pkgbase}-version-${pkgver}
  23   patch -p1 < "${srcdir}/jasper-1.900.1-fix-filename-buffer-overflow.patch"
  24   sed -r 's|(CMAKE_SKIP_BUILD_RPATH) FALSE|\1 TRUE|g' -i CMakeLists.txt
  25 }
  26
  27 build() {
  28   cd ${pkgbase}-version-${pkgver}
  29
  30   local options=(
  31     -DCMAKE_INSTALL_PREFIX=/usr
  32     -DCMAKE_INSTALL_LIBDIR=lib
  33     -DCMAKE_BUILD_TYPE=Release
  34     -DJAS_ENABLE_OPENGL=ON
  35     -DJAS_ENABLE_LIBJPEG=ON
  36     -DJAS_ENABLE_AUTOMATIC_DEPENDENCIES=OFF
  37     -DCMAKE_SKIP_RPATH=ON
  38   )
  39
  40   echo "Building static lib..."
  41   cmake \
  42     -B build-static \
  43     "${options[@]}" \
  44     -DJAS_ENABLE_SHARED=OFF
  45   make -C build-static
  46
  47   echo "Building shared lib..."
  48   cmake \
  49     -B build-shared \
  50     "${options[@]}" \
  51     -DJAS_ENABLE_SHARED=ON
  52   make -C build-shared
  53 }
  54
  55 check() {
  56   cd ${pkgbase}-version-${pkgver}/build-static
  57   make -j1 test
  58 }
  59
  60 package_jasper() {
  61   depends=('glibc' 'libjpeg' 'libjpeg.so')
  62   optdepends=('jasper-doc: documentation'
  63               'freeglut: jiv support'
  64               'glu: jiv support')
  65   provides=('libjasper.so')
  66   cd ${pkgbase}-version-${pkgver}
  67   make -C build-static DESTDIR="${pkgdir}" install
  68   make -C build-shared DESTDIR="${pkgdir}" install
  69   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  70   rm -r "${pkgdir}/usr/share/doc"
  71 }
  72
  73 package_jasper-doc() {
  74   pkgdesc+=' (documentation)'
  75   optdepends=('jasper')
  76   cd ${pkgbase}-version-${pkgver}
  77   make -C build-shared DESTDIR="${pkgdir}" install
  78   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  79   rm -rf "${pkgdir}/usr/"{bin,include,lib,share/man}
  80 }
  81
  82 # vim: ts=2 sw=2 et: