metis/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: jedbrown
   3 # Contributor: eleftg
   4 # Contributor: mickele
   5 # Contributor: gborzi
   6 # Contributor: abenson
   7
   8 pkgname=metis
   9 pkgver=5.1.0.p10
  10 _pkgver=5.1.0-p10
  11 pkgrel=2
  12 arch=(x86_64)
  13 pkgdesc="A set of serial programs for partitioning graphs, partitioning finite element meshes, and producing fill reducing orderings for sparse matrices"
  14 url="http://glaros.dtc.umn.edu/gkhome/metis/metis/overview"
  15 license=(custom)
  16 depends=(glibc)
  17 makedepends=(cmake)
  18 options=(docs)
  19 source=($pkgname-$pkgver.tar.bz2::https://bitbucket.org/petsc/pkg-metis/get/v$_pkgver.tar.bz2)
  20 sha256sums=('ddcb99746a8795ebb9d9c020acc31b85fe696eb2992c9ee5ac7588074a503a4b')
  21
  22 prepare() {
  23   mv petsc-pkg-metis-* $pkgname-$_pkgver
  24 }
  25
  26 build() {
  27   cmake -B build -S $pkgname-$_pkgver \
  28     -DCMAKE_INSTALL_PREFIX=/usr \
  29     -DSHARED=ON \
  30     -DMATH_LIB=m
  31   cmake --build build
  32 }
  33
  34 package() {
  35   DESTDIR="$pkgdir" cmake --install build
  36   install -m644 -D $pkgname-$_pkgver/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  37 }