orc/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgname=orc
   6 pkgver=0.4.32
   7 pkgrel=1
   8 pkgdesc="Optimized Inner Loop Runtime Compiler"
   9 url="https://gitlab.freedesktop.org/gstreamer/orc"
  10 arch=(x86_64)
  11 license=(custom:BSD)
  12 depends=(glibc)
  13 makedepends=(valgrind git gtk-doc meson)
  14 _commit=629864f073ae003e63c026c1de2407fec713cb53  # tags/0.4.32^0
  15 source=("git+https://gitlab.freedesktop.org/gstreamer/orc.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/^orc-//;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   DESTDIR="$pkgdir" meson install -C build
  38   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
  39 }