perl-file-slurper/repos/extra-any/PKGBUILD

   1 # Maintainer: Rémy Oudompheng <remy@archlinux.org>
   2
   3 pkgname=perl-file-slurper
   4 _dist=File-Slurper
   5 pkgver=0.012
   6 pkgrel=5
   7 pkgdesc="A simple, sane and efficient module to slurp a file"
   8 arch=('any')
   9 url="https://metacpan.org/release/${_dist}"
  10 license=('PerlArtistic' 'GPL')
  11 depends=('perl')
  12 checkdepends=('perl-test-warnings')
  13 options=('!emptydirs')
  14 source=(https://search.cpan.org/CPAN/authors/id/L/LE/LEONT/${_dist}-${pkgver}.tar.gz)
  15 md5sums=('5742c63096392dfee50b8db314bcca18')
  16 sha256sums=('4efb2ea416b110a1bda6f8133549cc6ea3676402e3caf7529fce0313250aa578')
  17
  18 build() {
  19     cd "${srcdir}/${_dist}-${pkgver}"
  20     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  21     export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  22     perl Makefile.PL
  23     make
  24 }
  25
  26 check() {
  27     cd "${srcdir}/${_dist}-${pkgver}"
  28     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  29     export PERL_MM_USE_DEFAULT=1
  30     make test
  31 }
  32
  33 package() {
  34     cd "${srcdir}/${_dist}-${pkgver}"
  35     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  36     make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  37 }