perl-net-ssleay/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Manolis Tzanidakis
   4
   5 pkgname=perl-net-ssleay
   6 _cpanname=Net-SSLeay
   7 pkgver=1.90
   8 pkgrel=2
   9 pkgdesc='Perl extension for using OpenSSL'
  10 url='https://search.cpan.org/dist/Net-SSLeay/'
  11 arch=('x86_64')
  12 license=('custom:BSD')
  13 depends=('openssl')
  14 makedepends=('chrpath')
  15 replaces=('net-ssleay')
  16 provides=('net-ssleay')
  17 options=('!emptydirs')
  18 source=(https://cpan.metacpan.org/authors/id/C/CH/CHRISN/${_cpanname}-${pkgver}.tar.gz)
  19 sha512sums=('8a5f251b5ef1d8c2d619d984594a7a22ddeed2e5e726fe683a45f299d7878f4ca8ffab00480ebf5ef7a94ae1fcf6be05dfdaa68b8bfe2ad68443150765adb891')
  20 b2sums=('2510fa886db8b7c5f185aa1145ae1b50b7c4101a9bd80e17c8c1d77718765f288c9180464d831775c35aa94b5a6f6c8f717ecaeb4974f7280829b63f10567f22')
  21
  22 build() {
  23   cd ${_cpanname}-${pkgver}
  24   PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  25   make
  26 }
  27
  28 check() {
  29   cd ${_cpanname}-${pkgver}
  30   make test
  31 }
  32
  33 package() {
  34   cd ${_cpanname}-${pkgver}
  35
  36   make install DESTDIR="${pkgdir}"
  37   install -Dm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}"
  38   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39
  40   # strip rpath
  41   find "${pkgdir}" -name '*.so' -exec chrpath -d '{}' \;
  42 }
  43
  44 # vim: ts=2 sw=2 et: