python-rdflib/trunk/PKGBUILD

   1 # Maintainer:
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Leif Warner <abimelech@gmail.com>
   4
   5 pkgname=python-rdflib
   6 pkgver=5.0.0
   7 pkgrel=5
   8 pkgdesc="A Python library for working with RDF, a simple yet powerful language for representing information"
   9 arch=('any')
  10 url="http://rdflib.net/"
  11 license=('BSD')
  12 depends=('python-isodate' 'python-pyparsing')
  13 optdepends=('python-html5lib: for html support'
  14             'python-requests: for sparql support')
  15 makedepends=('python-setuptools')
  16 checkdepends=('python-nose' 'python-six' 'python-html5lib' 'python-requests' 'python-networkx'
  17               'python-doctest-ignore-unicode')
  18 source=(rdflib-$pkgver.tar.gz::https://github.com/RDFLib/rdflib/tarball/$pkgver
  19         update-sparql-tests.patch)
  20 sha512sums=('d879c9312a5e6a69ef2edf7931f5e20f6d5c59ce6feb2397e5aeb09843f3568c284f9175b24ac4d513b720dcea82076776d33bfc4492f5d82a17c644586e7b48'
  21             'e60e9947b700ce34093a71cb400689f033d58f08a31aecedcca2a0223a6bd04cea645350da196a4b9ddd9727dbc92c840a924313ff2218042d53dd44633c53bc')
  22
  23 prepare() {
  24   cd RDFLib-rdflib-*
  25   patch -Np1 -i ../update-sparql-tests.patch
  26 }
  27
  28 build() {
  29   cd RDFLib-rdflib-*
  30   python setup.py build
  31 }
  32
  33 check() {
  34   cd RDFLib-rdflib-*
  35   #python setup.py test # Will download and install rdflib again
  36   nosetests3
  37 }
  38
  39 package() {
  40   cd RDFLib-rdflib-*
  41   python setup.py install --root="$pkgdir" --optimize=1
  42   install -Dm644  LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  43 }