qt5-wayland/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3
   4 pkgname=qt5-wayland
   5 pkgver=5.15.2+kde+r37
   6 pkgrel=1
   7 _commit=eb422ab5e07498a7a8d086f6a942ee35ab3c9776
   8 arch=('x86_64')
   9 url='https://www.qt.io'
  10 license=('GPL3' 'LGPL3' 'FDL' 'custom')
  11 pkgdesc='Provides APIs for Wayland'
  12 depends=('qt5-declarative' 'libxcomposite')
  13 makedepends=('vulkan-headers' 'git')
  14 groups=('qt' 'qt5')
  15 _pkgfqn=qtwayland
  16 source=(git+https://invent.kde.org/qt/qt/$_pkgfqn#commit=$_commit)
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $_pkgfqn
  21   echo "5.15.2+kde+r"`git rev-list --count origin/5.15.2..$_commit`
  22 }
  23
  24 prepare() {
  25   mkdir -p build
  26
  27   cd $_pkgfqn
  28   git revert -n 30cb2a87fcc6265232cb5a3ffce9836da6e531d6 # Revert version bump
  29 }
  30
  31 build() {
  32   cd build
  33
  34   qmake ../${_pkgfqn}
  35   make
  36 }
  37
  38 package() {
  39   cd build
  40
  41   make INSTALL_ROOT="$pkgdir" install
  42
  43   # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  44   find "$pkgdir/usr/lib" -type f -name '*.prl' \
  45     -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
  46
  47   install -d "$pkgdir"/usr/share/licenses
  48   ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
  49 }