ctags/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: John Proctor <jproctor@prium.net>
   4
   5 pkgname=ctags
   6 _commit=ca81123303640582358ce7b8a4e466615950a1f7  # p5.9.20210905.0
   7 pkgver=5.9.20210905.0
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc='Generates an index file of language objects found in source files'
  11 url='https://ctags.io/'
  12 arch=('x86_64')
  13 license=('GPL')
  14 depends=('glibc' 'libxml2' 'jansson' 'libyaml' 'libseccomp' 'libseccomp.so')
  15 makedepends=('git' 'python-docutils')
  16 provides=('universal-ctags')
  17 source=("git+https://github.com/universal-ctags/ctags.git#commit=$_commit")
  18 sha512sums=('SKIP')
  19
  20 pkgver() {
  21   git -C ctags describe --tags --match 'p*' | sed 's/^p//;s/\([^-]*-g\)/r\1/;s/-/./g'
  22 }
  23
  24 prepare() {
  25   cd ctags
  26   autoreconf -fiv
  27 }
  28
  29 build() {
  30   cd ctags
  31   ./configure \
  32     --prefix=/usr \
  33     --sysconfdir=/etc \
  34     --localstatedir=/var \
  35     --libexecdir=/usr/lib
  36   make
  37 }
  38
  39 check() {
  40   make -C ctags check
  41 }
  42
  43 package() {
  44   make -C ctags DESTDIR="${pkgdir}" install
  45 }
  46
  47 # vim:set sw=2 et: