desktop-file-utils/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: Alexander Fehr <pizzapunk gmail com>
   4
   5 pkgname=desktop-file-utils
   6 pkgver=0.26
   7 pkgrel=2
   8 pkgdesc="Command line utilities for working with desktop entries"
   9 arch=(x86_64)
  10 url="https://www.freedesktop.org/wiki/Software/desktop-file-utils"
  11 license=(GPL)
  12 depends=(glib2)
  13 makedepends=(git meson)
  14 _commit=54cec012921e52eb66b6ee1a1f40f2e9c9849f7c  # tags/0.26
  15 source=("git+https://gitlab.freedesktop.org/xdg/desktop-file-utils.git#commit=$_commit"
  16         update-desktop-database.hook)
  17 sha256sums=('SKIP'
  18             '501f1eb35d9fbbd61666f40302b0ce63425299edf023c075986a24dc3ef18575')
  19 validpgpkeys=('C01EDE5BB0D91E26D003662EC76BB9FEEAD12EA7') # Hans Petter Jansson <hpj@cl.no>
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28
  29   # Support Desktop Entry Spec 1.5
  30   git cherry-pick -n 425177a28b62 56d220dd679c
  31 }
  32
  33 build() {
  34   arch-meson $pkgname build
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   meson test -C build --print-errorlogs
  40 }
  41
  42 package() {
  43   depends+=(libglib-2.0.so)
  44
  45   meson install -C build --destdir "$pkgdir"
  46   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  47 }
  48
  49 # vim:set sw=2 et: