gucharmap/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan De Groot <jgc@archlinux.org>
   3
   4 pkgname=gucharmap
   5 pkgver=14.0.3
   6 pkgrel=1
   7 pkgdesc="Gnome Unicode Charmap"
   8 url="https://wiki.gnome.org/Apps/Gucharmap"
   9 arch=(x86_64)
  10 license=(GPL3)
  11 depends=(gtk3)
  12 makedepends=(gtk-doc gobject-introspection yelp-tools appdata-tools git meson
  13              unicode-character-database unzip vala)
  14 provides=(libgucharmap_2_90.so)
  15 options=(debug)
  16 _commit=c5ed6328814952e7a6e7997d02697119dc52eb90  # tags/14.0.3^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gucharmap.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build -D ucd_path=/usr/share/unicode
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40 }