pstoedit/trunk/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: damir <damir@archlinux.org>
   3 # Contributor: Tobias Powalowski <t.powa@gmx.de>
   4
   5 pkgname=pstoedit
   6 pkgver=3.78
   7 pkgrel=1
   8 pkgdesc="Translates PostScript and PDF graphics into other vector formats"
   9 arch=('x86_64')
  10 url="http://www.pstoedit.net/"
  11 license=('GPL')
  12 depends=('gcc-libs' 'plotutils' 'gd' 'imagemagick')
  13 makedepends=('ghostscript')
  14 source=("https://downloads.sourceforge.net/sourceforge/pstoedit/pstoedit-${pkgver}.tar.gz")
  15 sha512sums=('ed880da1ba16780224b4bb40d520f99bc5290b4335dd30f1a195855ce75b3880d5a4fca9885b214855ce61d8bd701aa0681a190e69a8fdef2f3d5e1e2f692648')
  16
  17 prepare() {
  18   cd "${srcdir}/${pkgname}-${pkgver}"
  19   sed -e 's|ImageMagick++|Magick++|' -i configure.ac
  20   autoreconf -vi
  21 }
  22
  23 build() {
  24   cd "${srcdir}/${pkgname}-${pkgver}"
  25   ./configure --prefix=/usr
  26   make
  27 }
  28
  29 package() {
  30   cd "${srcdir}/${pkgname}-${pkgver}"
  31   make DESTDIR="${pkgdir}" install
  32 }