pyside6/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgbase=pyside6
   5 pkgname=(shiboken6 pyside6)
   6 _qtver=6.3.1
   7 _clangver=14.0.6
   8 pkgver=${_qtver/-/}
   9 pkgrel=3
  10 arch=(x86_64)
  11 url='https://www.qt.io'
  12 license=(LGPL)
  13 makedepends=(cmake ninja clang llvm python-setuptools vulkan-headers python-numpy
  14              qt6-tools qt6-svg qt6-3d qt6-scxml qt6-datavis3d qt6-charts qt6-multimedia qt6-quick3d
  15              qt6-positioning qt6-networkauth qt6-remoteobjects qt6-sensors qt6-serialport qt6-connectivity
  16              qt6-webchannel qt6-webengine qt6-websockets qt6-shadertools)
  17 _pkgfn=pyside-setup-opensource-src-$_qtver
  18 source=(https://download.qt.io/official_releases/QtForPython/pyside6/PySide6-$pkgver-src/${_pkgfn}.tar.xz
  19         designer-plugin-install-dir.patch)
  20 sha256sums=('e5a85ed68834eb8324e3486283a9451b030d7221809e2a9533162e6b93899977'
  21             '66e895e07d5b01c64a94092353854c946fd7fc445b6181068dca290b5a3887e0')
  22 options=(debug)
  23
  24 prepare() {
  25   patch -d $_pkgfn -p1 < designer-plugin-install-dir.patch # Fix designer plugin install dir
  26 }
  27
  28 build() {
  29   cmake -B build -S $_pkgfn -G Ninja \
  30     -DCMAKE_INSTALL_PREFIX=/usr \
  31     -DCMAKE_BUILD_TYPE=None \
  32     -DBUILD_TESTS=OFF \
  33     -DPYTHON_EXECUTABLE=/usr/bin/python
  34   PYTHONPATH="$PWD"/build/sources \
  35   cmake --build build
  36 }
  37
  38 package_shiboken6() {
  39   pkgdesc='Generates bindings for C++ libraries using CPython source code'
  40   depends=(clang=$_clangver llvm libxslt qt6-base)
  41   optdepends=('python: Python bindings')
  42
  43   DESTDIR="$pkgdir" cmake --install build/sources/shiboken6
  44
  45 # Install egg-info
  46   export PATH="/usr/lib/qt6/bin:$PATH"
  47   cd $_pkgfn
  48   python setup.py egg_info --build-type=shiboken6
  49   _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
  50   cp -r shiboken6.egg-info "$pkgdir"/$_pythonpath
  51 }
  52
  53 package_pyside6() {
  54   pkgdesc='Enables the use of Qt6 APIs in Python applications'
  55   depends=(qt6-declarative shiboken6)
  56   optdepends=('qt6-tools: QtHelp, QtUiTools bindings'
  57               'qt6-svg: QtSvg bindings'
  58               'qt6-3d: Qt3D bindings'
  59               'qt6-quick3d: QtQuick3D bindings'
  60               'qt6-scxml: QtScxml bindings'
  61               'qt6-datavis3d: QtDataVisualization bindings'
  62               'qt6-charts: QtCharts bindings'
  63               'qt6-multimedia: QtMultimedia bindings'
  64               'qt6-serialport: QtSerialPort bindings'
  65               'qt6-webengine: QtWebEngine bindings'
  66               'qt6-remoteobjects: QtRemoteObjects bindings'
  67               'qt6-sensors: QtSensors bindings'
  68               'qt6-websockets: QtWebSockets bindings'
  69               'qt6-networkauth: QtNetworkAuth bindings')
  70
  71   DESTDIR="$pkgdir" cmake --install build/sources/pyside6
  72
  73 # Install egg-info
  74   export PATH="/usr/lib/qt6/bin:$PATH"
  75   cd $_pkgfn
  76   python setup.py egg_info --build-type=pyside6
  77   _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
  78   cp -r PySide6.egg-info "$pkgdir"/$_pythonpath
  79
  80 # Install pyi files
  81   install -Dm644 "$srcdir"/build/sources/pyside6/PySide6/*.pyi -t "$pkgdir"/usr/lib/python*/site-packages/PySide6
  82 }