rhash/trunk/PKGBUILD

   1 # Maintainer: Johannes Löthberg <johannes@kyriasis.com>
   2 # Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
   3 # Contributor: 謝致邦 <Yeking@Red54.com>
   4 # Contributor: cantabile <cantabile dot desu at gmail dot com>
   5 # Contributor: reMiND <detanator@gmail.com>
   6
   7 pkgname=rhash
   8 pkgver=1.4.2
   9 pkgrel=1
  10
  11 pkgdesc='Utility for verifying hash sums of files'
  12 url='https://github.com/rhash/RHash'
  13 license=('BSD')
  14 arch=('x86_64')
  15
  16 depends=('glibc')
  17
  18 backup=('etc/rhashrc')
  19
  20 source=(rhash-$pkgver.tar.gz::https://github.com/rhash/RHash/archive/v$pkgver.tar.gz
  21         rhash-$pkgver.tar.gz.asc::https://github.com/rhash/RHash/releases/download/v$pkgver/v$pkgver.tar.gz.asc)
  22
  23 sha512sums=('41df57e8b3f32c93d8e6f2ac668b32aaa23eb2eaf90a83f109e61e511404a5036ea88bcf2854e19c1ade0f61960e0d9edf01f3d82e1c645fed36579e9d7a6a25'
  24             'SKIP')
  25 # https://sourceforge.net/p/rhash/wiki/PublicKey/
  26 validpgpkeys=('2875F6B1C2D27A4F0C8AF60B2A714497E37363AE')
  27
  28 prepare() {
  29   cd RHash-$pkgver
  30   ./configure --prefix=/usr --sysconfdir=/etc --extra-cflags="$CFLAGS" --extra-ldflags="$LDFLAGS"
  31 }
  32
  33 build() {
  34   cd RHash-$pkgver
  35   make
  36 }
  37
  38 check() {
  39   cd RHash-$pkgver
  40   make test test-lib
  41 }
  42
  43 package() {
  44   cd RHash-$pkgver
  45
  46   # program
  47   make DESTDIR="$pkgdir" install
  48
  49   # library, since the makefiles are still broken
  50   make -C librhash DESTDIR="$pkgdir" install-lib-headers install-lib-shared install-so-link
  51
  52   # license
  53   install -Dm644 COPYING "$pkgdir"/usr/share/licenses/rhash/LICENSE
  54 }