telepathy-kde-auth-handler/kde-unstable/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Laurent Carlier <lordheavym@gmail.com>
   4
   5 pkgname=telepathy-kde-auth-handler
   6 _pkgname=ktp-auth-handler
   7 pkgver=22.07.90
   8 pkgrel=1
   9 pkgdesc='Provide UI/KWallet Integration For Passwords and SSL Errors on Account Connect'
  10 arch=(x86_64)
  11 url='https://community.kde.org/KTp'
  12 license=(GPL)
  13 groups=(kde-applications kde-network telepathy-kde)
  14 depends=(qca-qt5 telepathy-kde-common-internals)
  15 makedepends=(extra-cmake-modules)
  16 source=(https://download.kde.org/unstable/release-service/$pkgver/src/$_pkgname-$pkgver.tar.xz{,.sig})
  17 sha256sums=('c2d8e2476695f58d907856b0cee88ffa6a72185788ef44c0cf9f16a98393d131'
  18             'SKIP')
  19 validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
  20               F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
  21               D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
  22 options=(debug)
  23
  24 build() {
  25   cmake -B build -S $_pkgname-$pkgver \
  26     -DCMAKE_INSTALL_LIBEXECDIR=lib \
  27     -DBUILD_TESTING=OFF
  28   cmake --build build
  29 }
  30
  31 package() {
  32   DESTDIR="$pkgdir" cmake --install build
  33 }