bubblewrap/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2
   3 pkgbase=bubblewrap
   4 pkgname=(bubblewrap bubblewrap-suid)
   5 pkgver=0.6.1
   6 pkgrel=1
   7 pkgdesc='Unprivileged sandboxing tool'
   8 url='https://github.com/projectatomic/bubblewrap'
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(glibc libcap)
  12 makedepends=(libxslt docbook-xsl git meson bash-completion)
  13 _commit=a362d3c0ee79097ce2e3fca4ad003f1e96dad472  # tags/v0.6.1^0
  14 source=(git+$url#commit=$_commit)
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgbase
  19   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgbase
  24 }
  25
  26 build() {
  27   arch-meson $pkgbase build -D selinux=disabled
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package_bubblewrap() {
  36   meson install -C build --destdir "$pkgdir"
  37 }
  38
  39 package_bubblewrap-suid() {
  40   pkgdesc+=" (setuid variant)"
  41   provides=("bubblewrap=$pkgver-$pkgrel")
  42   conflicts=(bubblewrap)
  43
  44   meson install -C build --destdir "$pkgdir"
  45   chmod u+s "$pkgdir/usr/bin/bwrap"
  46 }