libcryptui/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=libcryptui
   5 pkgver=3.12.2+55+ged3b12af
   6 pkgrel=1
   7 pkgdesc="Library for OpenPGP prompts"
   8 url="https://gitlab.gnome.org/GNOME/libcryptui"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(gtk3 gpgme dbus-glib libnotify gcr dconf libsm)
  12 makedepends=(intltool gobject-introspection gnome-common git)
  13 provides=(libcryptui.so)
  14 _commit=ed3b12af71643d5f6d29fc6a5092123624faff6e  # master
  15 source=("git+https://gitlab.gnome.org/GNOME/libcryptui.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28 build() {
  29   cd $pkgname
  30   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  31               --disable-static --disable-schemas-compile --enable-gtk-doc
  32   make
  33 }
  34
  35 package() {
  36   cd $pkgname
  37   make DESTDIR="$pkgdir" install
  38 }