libfido2/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Karol Babioch <karol@babioch.de>
   3
   4 pkgname=libfido2
   5 pkgver=1.10.0
   6 pkgrel=1
   7 pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
   8 url='https://developers.yubico.com/libfido2/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so' 'zlib')
  12 makedepends=('cmake' 'systemd')
  13 provides=('libfido2.so')
  14 source=("https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz"{,.sig})
  15 sha512sums=('ba03e25d3f42f11cec74dee48c853ae35d03600f24ca06d2b751840408a132290fe22461372ae42ae31419061a63d9908c20a2c0cf3c0c9c8dbc46c34916784f'
  16             'SKIP')
  17 b2sums=('a4144ede774b90700f4cb1371b2acdba9d3ca8e6e0d68c5670986a1825635ebeb75f03c930da14a4539a9e075bcc5f7cfde7fbcc05e1fa383902ac6739225789'
  18         'SKIP')
  19 validpgpkeys=(
  20   'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro@yubico.com>
  21   '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail@yubico.com>
  22   '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas@yubico.com>
  23 )
  24
  25 build() {
  26   cd ${pkgname}-${pkgver}
  27   # do not use bundled udev rules superseded by systemd
  28   cmake -B build \
  29     -DCMAKE_INSTALL_PREFIX=/usr \
  30     -DCMAKE_INSTALL_LIBDIR=lib \
  31     -DCMAKE_BUILD_TYPE=Release \
  32     -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
  33     -Wno-dev \
  34     -S .
  35   make -C build VERBOSE=1
  36 }
  37
  38 package() {
  39   cd ${pkgname}-${pkgver}
  40   make -C build DESTDIR="${pkgdir}" install
  41   install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  42   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  43 }
  44
  45 # vim: ts=2 sw=2 et: