libsrtp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Yejun Yang <yejunx AT gmail DOT com>
   4 # Contributor: Michal Krenek <mikos@sg1.cz>
   5
   6 pkgname=libsrtp
   7 pkgver=2.4.2
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc="Library for SRTP (Secure Realtime Transport Protocol)"
  11 url="https://github.com/cisco/libsrtp"
  12 arch=(x86_64)
  13 license=(BSD)
  14 depends=(nss)
  15 makedepends=(git meson libpcap doxygen)
  16 checkdepends=(procps-ng)
  17 provides=("libsrtp${pkgver%%.*}.so")
  18 _commit=90d05bf8980d16e4ac3f16c19b77e296c4bc207b  # tags/v2.4.2
  19 source=("git+https://github.com/cisco/libsrtp#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/^v//;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29
  30   # Fixup pkgver: There are proper tags like v2.4.4
  31   # but also "moving tags" like v2 and v2.4 that aren't stable
  32   git tag | grep -Pv '^v\d+\.\d+\.\d+$' | xargs git tag -d
  33 }
  34
  35 build() {
  36   arch-meson $pkgname build \
  37     --buildtype release \
  38     -D crypto-library=nss \
  39     -D crypto-library-kdf=disabled
  40   meson compile -C build
  41   meson compile -C build doc
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50
  51   mkdir -p "$pkgdir/usr/share/doc"
  52   cp -a build/html "$pkgdir/usr/share/doc/$pkgname"
  53
  54   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/LICENSE
  55 }