irssi/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Dan McGee <dan@archlinux.org>
   4
   5 pkgname=irssi
   6 pkgver=1.4.4
   7 pkgrel=1
   8 pkgdesc='Modular text mode IRC client with Perl scripting'
   9 url='https://irssi.org/'
  10 arch=('x86_64')
  11 license=('GPL')
  12 depends=('glibc' 'glib2' 'openssl' 'libotr' 'perl' 'ncurses' 'libncursesw.so')
  13 makedepends=('meson' 'ninja')
  14 optdepends=('perl-libwww: for the scriptassist script')
  15 replaces=('irssi-otr')
  16 backup=('etc/irssi.conf')
  17 source=(https://github.com/irssi/irssi/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc})
  18 sha512sums=('da28ac7a527be301d0615d6d733e4cf4e09bb6d4f5c70bc33ff70e22439a01f197bb5d91b4432ca74d3ac2dbb3235f30d53efc63a4279de8664923c2ccdbdbea'
  19             'SKIP')
  20 validpgpkeys=('7EE65E3082A5FB06AC7C368D00CCB587DDBEF0E1') # The Irssi project <staff@irssi.org>
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   arch-meson Build \
  25     -Dwith-perl-lib=vendor \
  26     -Dwith-proxy=yes \
  27     -Dwith-otr=yes \
  28     -Dwith-perl=yes \
  29     -Denable-true-color=yes
  30   ninja -C Build
  31 }
  32
  33 package() {
  34   cd ${pkgname}-${pkgver}
  35   DESTDIR="${pkgdir}" ninja -C Build install
  36   install -Dm 644 irssi.conf "${pkgdir}"/etc/irssi.conf
  37 }
  38
  39 # vim: ts=2 sw=2 et: