libhandy0/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=libhandy0
   5 pkgver=0.0.13+12+gaa6b6f4
   6 pkgrel=3
   7 pkgdesc="Library full of GTK+ widgets for mobile phones"
   8 url="https://gitlab.gnome.org/GNOME/libhandy"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2 gtk3)
  12 makedepends=(git gobject-introspection meson vala)
  13 checkdepends=(xorg-server-xvfb)
  14 provides=(libhandy-0.0.so)
  15 _commit=aa6b6f43d505383538a2a3e7b4fcdd6a8ada85ff  # libhandy-0-0
  16 source=("git+https://gitlab.gnome.org/GNOME/libhandy.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 prepare() {
  20   cd libhandy
  21 }
  22
  23 pkgver() {
  24   cd libhandy
  25   git describe --tags | sed 's/^v//;s/-/+/g'
  26 }
  27
  28 build() {
  29   arch-meson libhandy build \
  30     -D glade_catalog=disabled \
  31     -D examples=false
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   dbus-run-session xvfb-run \
  37     -s '-screen 0 1920x1080x24 -nolisten local' \
  38     meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   DESTDIR="$pkgdir" meson install -C build
  43 }
  44
  45 # vim:set sw=2 et: