pygobject/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=pygobject
   5 pkgname=(python-gobject)
   6 pkgver=3.44.1
   7 pkgrel=3
   8 pkgdesc="Python Bindings for GLib/GObject/GIO/GTK+"
   9 url="https://wiki.gnome.org/Projects/PyGObject"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(
  13   gobject-introspection-runtime
  14   python
  15 )
  16 makedepends=(
  17   git
  18   gobject-introspection
  19   meson
  20   python-cairo
  21 )
  22 checkdepends=(
  23   gtk3
  24   python-pytest
  25   xorg-server-xvfb
  26 )
  27 optdepends=('cairo: Cairo bindings')
  28 provides=("pygobject-devel=$pkgver")
  29 conflicts=(pygobject-devel)
  30 replaces=('pygobject-devel<=3.36.1-1')
  31 _commit=1a2544c898ca2aafcab0c9e472be22657f310cf3  # tags/3.44.1^0
  32 source=(
  33   "git+https://gitlab.gnome.org/GNOME/pygobject.git#commit=$_commit"
  34 )
  35 b2sums=('SKIP')
  36
  37 pkgver() {
  38   cd pygobject
  39   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  40 }
  41
  42 prepare() {
  43   cd pygobject
  44 }
  45
  46 build() {
  47   arch-meson pygobject build
  48   meson compile -C build
  49 }
  50
  51 check() {
  52   PYTEST_ADDOPTS="-v" PYGI_TEST_VERBOSE=1 \
  53     xvfb-run -s '-nolisten local' \
  54     meson test -C build --print-errorlogs
  55 }
  56
  57 package_python-gobject() {
  58   meson install -C build --destdir "$pkgdir"
  59   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  60   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  61 }
  62
  63 # vim:set sw=2 sts=-1 et: