atkmm-2.36/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=atkmm-2.36
   5 pkgname=(atkmm-2.36 atkmm-2.36-docs)
   6 pkgver=2.36.2
   7 pkgrel=1
   8 pkgdesc="C++ bindings for ATK"
   9 url="https://www.gtkmm.org/"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(atk glibmm-2.68)
  13 makedepends=(git meson mm-common glibmm-2.68-docs)
  14 options=(!emptydirs)
  15 _commit=4829d5f55c02b8a72e261c4ee097082693792e5d  # tags/2.36.2^0
  16 source=("git+https://gitlab.gnome.org/GNOME/atkmm.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd atkmm
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd atkmm
  26 }
  27
  28 build() {
  29   arch-meson atkmm build -D maintainer-mode=true
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package_atkmm-2.36() {
  38   depends+=(libsigc-3.0.so libglibmm-2.68.so)
  39   provides=(libatkmm-2.36.so)
  40
  41   meson install -C build --destdir "$pkgdir"
  42
  43   # Split -docs
  44   mkdir -p docs/usr/share
  45   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  46 }
  47
  48 package_atkmm-2.36-docs() {
  49   pkgdesc+=" (documentation)"
  50   depends=()
  51   options=(!strip)
  52
  53   mv -t "$pkgdir" docs/*
  54 }