gnome-calculator/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-calculator
   5 pkgver=44.0
   6 pkgrel=1
   7 pkgdesc="GNOME Scientific calculator"
   8 url="https://wiki.gnome.org/Apps/Calculator"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(
  12   dconf
  13   gtksourceview5
  14   libadwaita
  15   libgee
  16   libmpc
  17   libsoup3
  18   mpfr
  19 )
  20 makedepends=(
  21   git
  22   gobject-introspection
  23   meson
  24   vala
  25   yelp-tools
  26 )
  27 provides=(
  28   libgcalc-2.so
  29   libgci-1.so
  30 )
  31 groups=(gnome)
  32 _commit=2fc61459192ffa7ad91acdbafb4d692a20743bca  # tags/44.0^0
  33 source=("git+https://gitlab.gnome.org/GNOME/gnome-calculator.git#commit=$_commit")
  34 b2sums=('SKIP')
  35
  36 pkgver() {
  37   cd $pkgname
  38   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  39 }
  40
  41 build() {
  42   arch-meson $pkgname build
  43   meson compile -C build
  44 }
  45
  46 check() {
  47   meson test -C build --print-errorlogs
  48 }
  49
  50 package() {
  51   meson install -C build --destdir "$pkgdir"
  52 }
  53
  54 # vim:set sw=2 sts=-1 et: