gnome-control-center/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-control-center
   5 pkgver=44.1
   6 pkgrel=2
   7 pkgdesc="GNOME's main interface to configure various aspects of the desktop"
   8 url="https://gitlab.gnome.org/GNOME/gnome-control-center"
   9 license=(GPL3)
  10 arch=(x86_64)
  11 depends=(
  12   accountsservice
  13   bolt
  14   colord-gtk4
  15   cups-pk-helper
  16   gcr
  17   gnome-bluetooth-3.0
  18   gnome-color-manager
  19   gnome-desktop-4
  20   gnome-online-accounts
  21   gnome-settings-daemon
  22   gnome-shell
  23   gsettings-desktop-schemas
  24   gsound
  25   gtk4
  26   libadwaita
  27   libgnomekbd
  28   libgtop
  29   libgudev
  30   libibus
  31   libmalcontent
  32   libmm-glib
  33   libnma-gtk4
  34   libpwquality
  35   smbclient
  36   sound-theme-freedesktop
  37   udisks2
  38   upower
  39 )
  40 makedepends=(
  41   docbook-xsl
  42   git
  43   meson
  44   modemmanager
  45   python
  46 )
  47 checkdepends=(
  48   python-dbusmock
  49   python-gobject
  50   xorg-server-xvfb
  51 )
  52 optdepends=(
  53   'fwupd: device security panel'
  54   'gnome-remote-desktop: screen sharing'
  55   'gnome-user-share: WebDAV file sharing'
  56   'malcontent: application permission control'
  57   'networkmanager: network settings'
  58   'openssh: remote login'
  59   'power-profiles-daemon: power profiles'
  60   'rygel: media sharing'
  61   'system-config-printer: printer settings'
  62 )
  63 groups=(gnome)
  64 _commit=da661203820d5766ff10fd7f64d2117470c70a2a  # tags/44.1^0
  65 source=(
  66   "git+https://gitlab.gnome.org/GNOME/gnome-control-center.git#commit=$_commit"
  67   "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
  68   pixmaps-dir.diff
  69 )
  70 sha256sums=('SKIP'
  71             'SKIP'
  72             '8695bc08c06026b7bfdd43941b4e07bb3ffbaa4e709be0b23ee138d24b6dbc8f')
  73
  74 pkgver() {
  75   cd $pkgname
  76   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  77 }
  78
  79 prepare() {
  80   cd $pkgname
  81
  82   # Install bare logos into pixmaps, not icons
  83   git apply -3 ../pixmaps-dir.diff
  84
  85   git submodule init subprojects/gvc
  86   git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
  87   git -c protocol.file.allow=always submodule update
  88 }
  89
  90
  91 build() {
  92   local meson_options=(
  93     -D documentation=true
  94     -D malcontent=true
  95   )
  96
  97   arch-meson $pkgname build "${meson_options[@]}"
  98   meson compile -C build
  99 }
 100
 101 check() {
 102   GTK_A11Y=none meson test -C build --print-errorlogs
 103 }
 104
 105 package() {
 106   meson install -C build --destdir "$pkgdir"
 107   install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
 108 }
 109
 110 # vim:set sw=2 sts=-1 et: