gnome-taquin/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-taquin
   5 pkgver=3.38.1+r35+g35edb95
   6 pkgrel=1
   7 pkgdesc="Move tiles so that they reach their places"
   8 url="https://wiki.gnome.org/Apps/Taquin"
   9 arch=(x86_64)
  10 license=(GPL3)
  11 depends=(gtk3 librsvg gsound)
  12 makedepends=(meson vala yelp-tools appstream-glib git)
  13 groups=(gnome-extra)
  14 options=(debug)
  15 _commit=35edb95303b75559607d0599c4424c6cbc661648  # master
  16 source=("git+https://gitlab.gnome.org/GNOME/gnome-taquin.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   meson install -C build --destdir="$pkgdir"
  39 }
  40
  41 # vim:set sw=2 sts=-1 et: