gnome-user-share/trunk/PKGBUILD

   1 # Contributor: Roman Kyrylych <roman@archlinux.org>
   2
   3 pkgname=gnome-user-share
   4 pkgver=43.0
   5 pkgrel=1
   6 pkgdesc="Easy to use user-level file sharing for GNOME"
   7 url="https://gitlab.gnome.org/GNOME/gnome-user-share"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(glib2 dconf mod_dnssd systemd)
  11 makedepends=(git meson)
  12 groups=(gnome)
  13 _commit=a0e790aa9494db9d1b1f48b4fc0d2f78e112044d  # tags/43.0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gnome-user-share.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   local meson_options=(
  28     -D httpd=/usr/bin/httpd
  29     -D modules_path=/usr/lib/httpd/modules
  30   )
  31
  32   arch-meson $pkgname build "${meson_options[@]}"
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }
  43
  44 # vim:set sw=2 sts=-1 et: