goffice/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Aaron Griffin <aaron@archlinux.org>
   3
   4 pkgname=goffice
   5 pkgver=0.10.55
   6 pkgrel=1
   7 pkgdesc="A GLib/GTK+ set of document-centric objects and charting library"
   8 url="https://git.gnome.org/browse/goffice"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(librsvg gtk3 libgsf libspectre libxslt lasem)
  12 makedepends=(intltool gtk-doc gobject-introspection autoconf-archive git)
  13 _commit=29c5bfe6333b499a051f969464c6804e28616736
  14 source=("git+https://gitlab.gnome.org/GNOME/goffice.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^GOFFICE_//;s/_/./g;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd $pkgname
  29   ./configure --prefix=/usr --sysconfdir=/etc \
  30       --localstatedir=/var --disable-static --enable-introspection --enable-gtk-doc
  31
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33   make
  34 }
  35
  36 package() {
  37   cd $pkgname
  38   make DESTDIR="${pkgdir}" install
  39 }