libcryptui/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=libcryptui
   5 pkgver=3.12.2+r71+ged4f890e
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="Library for OpenPGP prompts"
   9 url="https://gitlab.gnome.org/GNOME/libcryptui"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gtk3 gpgme dbus-glib libnotify gcr dconf libsm)
  13 makedepends=(intltool gobject-introspection gnome-common git)
  14 provides=(libcryptui.so)
  15 _commit=ed4f890ee29b94c1bedd7030d5c857e3b9edb465  # master
  16 source=("git+https://gitlab.gnome.org/GNOME/libcryptui.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd $pkgname
  31   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  32               --disable-static --disable-schemas-compile --enable-gtk-doc
  33   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: