libisl/trunk/PKGBUILD

   1 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   2 # Contributor: Andrew Sun  <adsun701 at gmail dot com>
   3 # Contributor: Kritias     <theodoridisgr at gmail dot com>
   4 # Contributor: sudokode    <sudokode at gmail dot com>
   5 # Contributor: Allan McRae <allan at archlinux dot org>
   6
   7 pkgname=libisl
   8 pkgver=0.26
   9 pkgrel=1
  10 pkgdesc='Library for manipulating sets and relations of integer points bounded by linear constraints'
  11 arch=('x86_64')
  12 url='https://libisl.sourceforge.io'
  13 license=('MIT')
  14 depends=('gmp')
  15 provides=('isl' 'libisl.so')
  16 replaces=('isl')
  17 options=(staticlibs)
  18 source=("https://libisl.sourceforge.io/isl-${pkgver}.tar.xz")
  19 b2sums=('2cfe2e0774a991d2385e66f58490c5454382cabc82d74eb4bbe5a603293b7bdc34ca3b087f0884f9da319c447747edc76275ecaf2f171237939f9c7d3c52ced7')
  20
  21 build() {
  22   cd "${srcdir}"/${pkgname#lib}-${pkgver}
  23   ./configure --prefix=/usr
  24   make
  25 }
  26
  27 check() {
  28   cd "${srcdir}"/${pkgname#lib}-${pkgver}
  29   make check || true
  30 }
  31
  32 package() {
  33   cd "${srcdir}"/${pkgname#lib}-${pkgver}
  34
  35   make DESTDIR="${pkgdir}" install
  36
  37   install -dm755 "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  38   mv "${pkgdir}"/usr/lib/libisl.so.*-gdb.py "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  39
  40   install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  41 }