libnghttp2/trunk/PKGBUILD

   1 # Maintainer: Anatol Pomozov
   2 # Contributor: Zhuoyun Wei <wzyboy@wzyboy.org>
   3
   4 pkgname=libnghttp2
   5 _tag='6c023db8a758c19b0adff8fa13e175cf3d7b61b4' # git rev-parse v${pkgver}
   6 pkgver=1.52.0
   7 pkgrel=2
   8 pkgdesc='Framing layer of HTTP/2 is implemented as a reusable C library'
   9 arch=('x86_64')
  10 url='https://nghttp2.org/'
  11 license=('MIT')
  12 depends=('glibc')
  13 makedepends=('git')
  14 conflicts=('nghttp2<1.20.0-2')
  15 validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
  16 source=("git+https://github.com/nghttp2/nghttp2.git#tag=${_tag}?signed")
  17 sha512sums=('SKIP')
  18
  19 prepare() {
  20   cd nghttp2
  21
  22   autoreconf -i
  23 }
  24
  25 build() {
  26   cd nghttp2
  27
  28   ./configure \
  29     --prefix=/usr \
  30     --disable-examples \
  31     --disable-python-bindings \
  32     --enable-lib-only
  33   make
  34 }
  35
  36 check() {
  37   cd nghttp2
  38   make check
  39 }
  40
  41 package() {
  42   cd nghttp2/lib
  43
  44   make DESTDIR="$pkgdir" install
  45   install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/libnghttp2/COPYING"
  46 }