lprint/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: WorMzy Tykashi <wormzy.tykashi@gmail.com>
   3
   4 pkgname=lprint
   5 pkgver=1.2.0
   6 pkgrel=1
   7 pkgdesc="Label Printer Application"
   8 arch=('x86_64')
   9 url="https://www.msweet.org/lprint/"
  10 license=('Apache' 'custom')
  11 depends=('pappl' 'libcups' 'libpng' 'libusb' 'pam')
  12 options=('debug')
  13 source=("https://github.com/michaelrsweet/lprint/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz"{,.sig})
  14 validpgpkeys=('845464660B686AAB36540B6F999559A027815955')  # "Michael R Sweet <michael.r.sweet@gmail.com>"
  15 #validpgpkeys=('9086C3CDC66C3F563CF8F405BE67C75EC81F3244') # "Michael R Sweet <msweet@msweet.org>"
  16 sha256sums=('96a2f7efbbd318cc7189c4b1d59894caee02503a881a82d7a212d2a94636f95c'
  17             'SKIP')
  18
  19 build() {
  20   cd ${pkgname}-${pkgver}
  21   ./configure --prefix=/usr --with-systemd
  22   make
  23 }
  24
  25 check() {
  26    cd "$pkgname-$pkgver"
  27 #   make -k check
  28 }
  29
  30 package() {
  31   cd ${pkgname}-${pkgver}
  32   make DESTDIR="${pkgdir}" install
  33   # add license + exception
  34   install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" {LICENSE,NOTICE}
  35
  36   # workaround until next release - FS#75465 / https://github.com/michaelrsweet/lprint/pull/63
  37   sed -i "s:/local::" "${pkgdir}"/usr/lib/systemd/system/lprint.service
  38 }