noto-fonts/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 pkgbase=noto-fonts
   4 pkgname=(noto-fonts noto-fonts-extra)
   5 pkgver=20230501
   6 _commit=8f03a57b371df199e1c73b2bd5d342fbbe4ce840
   7 pkgrel=1
   8 pkgdesc='Google Noto TTF fonts'
   9 arch=(any)
  10 url='https://fonts.google.com/noto'
  11 license=(custom:SIL)
  12 makedepends=(git)
  13 source=(git+https://github.com/notofonts/notofonts.github.io#commit=$_commit
  14         66-noto-sans.conf 66-noto-serif.conf 66-noto-mono.conf
  15         46-noto-sans.conf 46-noto-serif.conf 46-noto-mono.conf)
  16 sha256sums=('SKIP'
  17             '52684bebf6447be22618d2a04ff37623ec92f9d8ccf6b6f972e5bcbcfee90d69'
  18             '4459944b63dc083107280f5d7375c69746bf80a09416a4a4909a100e58e5a33a'
  19             '4526289f59654e2a81dc734669a1ae4e416f9a56d0896ec3741c6bf065baf8a8'
  20             '83a8faf6a47954075f97a2d555048e2a6689c38603b2ca00150157bf645f4593'
  21             'c94368b24506770767d003e5bcba589a8e402e489c240ee52453bf3ac7e9b5fa'
  22             'f5c09b37280d7569b6c99a78511639be4ae25b8c5406464422fe0421fe13a884')
  23
  24 package_noto-fonts() {
  25   optdepends=('noto-fonts-cjk: CJK characters' 'noto-fonts-emoji: Emoji characters'
  26               'noto-fonts-extra: additional variants (condensed, semi-bold, extra-light)')
  27   provides=(ttf-font)
  28
  29   cd notofonts
  30   install -Dm644 fonts/*/hinted/ttf/*.tt[fc] -t "$pkgdir"/usr/share/fonts/noto
  31   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/noto-fonts
  32
  33   # Move to noto-fonts-extra
  34   rm -f "$pkgdir"/usr/share/fonts/noto/Noto*{-Condensed,-Semi,-Extra}*.ttf
  35
  36   # Install fontconfig files
  37   install -Dm644 "$srcdir"/*.conf -t "$pkgdir"/usr/share/fontconfig/conf.avail/
  38   install -d "$pkgdir"/usr/share/fontconfig/conf.default
  39   ln -rs "$pkgdir"/usr/share/fontconfig/conf.avail/* "$pkgdir"/usr/share/fontconfig/conf.default
  40 }
  41
  42 package_noto-fonts-extra() {
  43   pkgdesc+=' - additional variants'
  44   depends=(noto-fonts)
  45
  46   cd notofonts
  47   install -Dm644 fonts/*/hinted/ttf/*{-Condensed,-Semi,-Extra}*.tt[fc] -t "$pkgdir"/usr/share/fonts/noto
  48 }