sof-bin/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=sof-bin
   4 pkgname=(sof-firmware sof-tools)
   5 pkgver=2.2.4
   6 pkgrel=1
   7 pkgdesc="Sound Open Firmware"
   8 url="https://www.sofproject.org/"
   9 arch=(x86_64)
  10 license=(custom:BSD custom:ISC)
  11 _binver=v${pkgver}
  12 source=(https://github.com/thesofproject/sof-bin/releases/download/$_binver/sof-bin-$_binver.tar.gz)
  13 sha256sums=('ce8aaeba103aa56a82662552b0f33f33a859aa1008d8bfbc2c22f0ccfc8c6b3a')
  14
  15 package_sof-firmware() {
  16   options+=(!strip)
  17
  18   local fwdir="$pkgdir/usr/lib/firmware/intel"
  19   mkdir -p "$fwdir"
  20
  21   cd sof-bin-$_binver
  22
  23   cp -at "$fwdir" sof-$_binver
  24   ln -sr "$fwdir"/{sof-$_binver,sof}
  25
  26   cp -at "$fwdir" sof-tplg-$_binver
  27   ln -sr "$fwdir"/{sof-tplg-$_binver,sof-tplg}
  28
  29   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  30 }
  31
  32 package_sof-tools() {
  33   pkgdesc+=" - tools"
  34   depends=(alsa-lib)
  35
  36   cd sof-bin-$_binver
  37
  38   install -Dt "$pkgdir/usr/bin" tools-$_binver/*
  39   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: