speex/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jason Chu <jason@archlinux.org>
   3
   4 pkgname=speex
   5 pkgver=1.2.1
   6 pkgrel=1
   7 pkgdesc="A free codec for free speech"
   8 url="https://www.speex.org/"
   9 arch=(x86_64)
  10 license=(BSD)
  11 depends=(gcc-libs libogg speexdsp)
  12 makedepends=(git)
  13 _commit=5dceaaf3e23ee7fd17c80cb5f02a838fd6c18e01  # tags/Speex-1.2.1^0
  14 source=("git+https://gitlab.xiph.org/xiph/speex.git#commit=$_commit")
  15 b2sums=('SKIP')
  16
  17 pkgver() {
  18   cd speex
  19   git describe --tags | sed 's/^Speex-//;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd speex
  24   ./autogen.sh
  25 }
  26
  27 build() {
  28   cd speex
  29   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  30     --enable-binaries \
  31     --disable-static
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33   make
  34 }
  35
  36 check() {
  37   cd speex
  38   make -k check
  39 }
  40
  41 package() {
  42   depends+=(libogg.so libspeexdsp.so)
  43   provides+=(libspeex.so)
  44
  45   cd speex
  46   make DESTDIR="$pkgdir" install
  47   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  48 }