webrtc-audio-processing/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=webrtc-audio-processing
   4 pkgver=0.3.1
   5 pkgrel=3
   6 pkgdesc="AudioProcessing library based on Google's implementation of WebRTC"
   7 url="https://freedesktop.org/software/pulseaudio/webrtc-audio-processing/"
   8 arch=(x86_64)
   9 license=(custom)
  10 depends=(gcc-libs)
  11 makedepends=(git)
  12 provides=(libwebrtc_audio_processing.so)
  13 _commit=e882a5442ac22c93648e12837248d651d18b9247  # tags/v0.3.1^0
  14 source=("git+https://gitlab.freedesktop.org/pulseaudio/webrtc-audio-processing.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^v//;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd $pkgname
  29   ./configure --prefix=/usr --disable-static
  30   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  31   make
  32 }
  33
  34 check() {
  35   cd $pkgname
  36   make check
  37 }
  38
  39 package() {
  40   cd $pkgname
  41   make DESTDIR="$pkgdir" install
  42   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  43 }
  44
  45 # vim:set sw=2 et: