gitg/repos/testing-x86_64/PKGBUILD

   1 # Contributor: Eric Bélanger <eric@archlinux.org>
   2
   3 pkgname=gitg
   4 pkgver=3.32.1+r23+g33bb5d2d
   5 pkgrel=2
   6 epoch=2
   7 pkgdesc="GNOME GUI client to view git repositories"
   8 url="https://wiki.gnome.org/Apps/Gitg"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(gtksourceview3 git libgit2-glib libgee webkit2gtk libpeas gtkspell3
  12          python-gobject libdazzle)
  13 makedepends=(gobject-introspection git meson vala)
  14 _commit=33bb5d2d896fcf2fc9a2ed50b236b727c5364895  # gnome-3-32
  15 source=("git+https://gitlab.gnome.org/GNOME/gitg.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd gitg
  20   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd gitg
  25
  26   # fix tests
  27   git cherry-pick -n b9f102c760adaee8185567007bcbe3b6604754f2
  28 }
  29
  30 build() {
  31   arch-meson gitg build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  42   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  43 }