gnome-user-share/trunk/PKGBUILD

   1 # Contributor: Roman Kyrylych <roman@archlinux.org>
   2
   3 pkgname=gnome-user-share
   4 pkgver=3.34.0
   5 pkgrel=2
   6 pkgdesc="Easy to use user-level file sharing for GNOME"
   7 arch=(x86_64)
   8 url="https://gitlab.gnome.org/GNOME/gnome-user-share"
   9 license=(GPL)
  10 depends=(mod_dnssd dconf gtk3 libnotify libcanberra)
  11 makedepends=(libnautilus-extension git meson yelp-tools)
  12 groups=(gnome)
  13 _commit=6f5213ad76e78f0ea3040610ce9fa94a59505913  # tags/GNOME_USER_SHARE_3_34_0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gnome-user-share.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^GNOME_USER_SHARE_//;s/_/./g;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build \
  28     -D httpd=/usr/bin/httpd \
  29     -D modules_path=/usr/lib/httpd/modules \
  30     -D nautilus_extension=true
  31   ninja -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   DESTDIR="$pkgdir" meson install -C build
  40 }