mesa-demos/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 pkgbase=mesa-demos
   4 pkgname=('mesa-demos' 'mesa-utils')
   5 pkgver=8.4.0
   6 pkgrel=6
   7 arch=('x86_64')
   8 url="https://www.mesa3d.org/"
   9 license=('custom')
  10 makedepends=('mesa' 'freetype2' 'git'
  11              'glew' 'freeglut')
  12 source=(https://mesa.freedesktop.org/archive/demos/mesa-demos-$pkgver.tar.bz2{,.sig}
  13         'LICENSE')
  14 sha512sums=('b72d03cad36e0535ff18dcfb222ec4200064b9264f6da51a6e5f03b0dd912abe188bc1d600b6698de3ce6f63b28d2ce01565886ca8e7079edc4967fbf2fb0957'
  15             'SKIP'
  16             '25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2')
  17 validpgpkeys=('E390B9700582FAEA959ACAD41EEF53D38A3A9C67') # "Andreas Boll <andreas.boll.dev@gmail.com>"
  18
  19 build() {
  20   cd mesa-demos-$pkgver
  21   ./configure --prefix=/usr \
  22     --disable-gles1 \
  23     --with-system-data-files=/usr/share/mesa-demos
  24
  25   make
  26 }
  27
  28 package_mesa-demos() {
  29
  30   pkgdesc="Mesa demos"
  31   install=mesa-demos.install
  32   depends=('glew' 'freeglut')
  33
  34   cd mesa-demos-$pkgver
  35   make DESTDIR="${pkgdir}" install
  36
  37   # add missing egl files
  38   install -m 0755 src/egl/opengl/{eglgears_x11,eglkms,egltri_x11,peglgears,xeglgears,xeglthreads} "${pkgdir}/usr/bin/"
  39
  40   install -m755 -d "${pkgdir}/usr/share/licenses/mesa-demos"
  41   install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/"
  42
  43   # remove utils
  44   rm ${pkgdir}/usr/bin/{glxinfo,glxgears,eglinfo}
  45 }
  46
  47 package_mesa-utils() {
  48
  49   pkgdesc="essential Mesa utilities"
  50   depends=('libgl')
  51   provides=('glxinfo' 'glxgears' 'eglinfo')
  52
  53   cd mesa-demos-$pkgver
  54   install -Dm 0755 src/egl/opengl/eglinfo -t "${pkgdir}/usr/bin/"
  55   install -Dm 0755 src/xdemos/{glxinfo,glxgears} -t "${pkgdir}/usr/bin/"
  56
  57
  58   install -m755 -d "${pkgdir}/usr/share/licenses/$pkgname"
  59   install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/"
  60 }