rest/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2
   3 pkgname=rest
   4 pkgver=0.8.1
   5 pkgrel=3
   6 pkgdesc="Helper library for RESTful services"
   7 url="https://wiki.gnome.org/Projects/Librest"
   8 arch=(x86_64)
   9 license=(LGPL2.1)
  10 depends=(glib2 libxml2 libsoup)
  11 makedepends=(gobject-introspection gtk-doc git)
  12 provides=(librest{,-extras}-0.7.so)
  13 _commit=2971b3b92701f70fc368ad64bd25cefaea043f87  # tags/0.8.1^0
  14 source=("git+https://gitlab.gnome.org/GNOME/librest.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd librest
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd librest
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd librest
  29   ./configure --prefix=/usr --sysconfdir=/etc --enable-gtk-doc
  30   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  31   make
  32 }
  33
  34 package() {
  35   cd librest
  36   make DESTDIR="$pkgdir" install
  37 }
  38
  39 # vim:set ts=2 sw=2 et: