dconf/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=dconf
   5 pkgver=0.40.0
   6 pkgrel=2
   7 pkgdesc="Configuration database system"
   8 url="https://wiki.gnome.org/Projects/dconf"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2)
  12 makedepends=(vala dbus git gtk-doc python meson bash-completion)
  13 provides=(libdconf.so)
  14 options=(debug)
  15 install=dconf.install
  16 _commit=4c0a26052efafae923eba42d14c5cb88da745de2  # tags/0.40.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/dconf.git#commit=$_commit"
  18         dconf-update dconf-update.hook)
  19 sha256sums=('SKIP'
  20             '330142605370f82f4229e8a94b245f911407eb629b50f1497f415c70164a90ec'
  21             '8d02176ff001a13d15a7ac087edd2502725494668933fa2c6e6f9cb21ae24e6b')
  22
  23 pkgver() {
  24   cd dconf
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd dconf
  30 }
  31
  32 build() {
  33   arch-meson dconf build -D gtk_doc=true
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   meson install -C build --destdir "$pkgdir"
  43
  44   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  45   install -Dt "$pkgdir/usr/share/libalpm/scripts" dconf-update
  46
  47   # Prevent this directory from getting removed when other
  48   # packages which install files there get uninstalled
  49   install -Dm644 /dev/null "$pkgdir/etc/dconf/db/.placeholder"
  50 }
  51
  52 # vim:set sw=2 sts=-1 et: