gmime3/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Ben <ben@benmazer.net>
   4
   5 pkgname=gmime3
   6 pkgver=3.2.13
   7 pkgrel=1
   8 pkgdesc="A C/C++ MIME creation and parser library with support for S/MIME, PGP, and Unix mbox spools"
   9 url="https://github.com/jstedfast/gmime"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(glib2 gpgme zlib libidn2)
  13 makedepends=(gobject-introspection gtk-doc git vala docbook-utils)
  14 provides=(libgmime-3.0.so)
  15 _commit=da1b041a2ce7e5e5c9d2c3e9499fe71b7a84d222  # tags/3.2.13^0
  16 source=("git+https://github.com/jstedfast/gmime#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd gmime
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd gmime
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd gmime
  31   ./configure \
  32     --prefix=/usr \
  33     --sysconfdir=/etc \
  34     --localstatedir=/var \
  35     --enable-gtk-doc \
  36     --enable-smime \
  37     --disable-static
  38   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  39   make
  40 }
  41
  42 check() {
  43   cd gmime
  44   make check
  45 }
  46
  47 package() {
  48   cd gmime
  49   make DESTDIR="$pkgdir" install
  50 }