gthumb/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias@justdreams.de>
   4
   5 pkgname=gthumb
   6 pkgver=3.12.2
   7 pkgrel=5
   8 pkgdesc="Image browser and viewer for the GNOME Desktop"
   9 url="https://wiki.gnome.org/Apps/gthumb"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
  13          libsecret libsoup webkit2gtk json-glib gst-plugin-gtk libjxl libheif)
  14 makedepends=(exiv2 brasero libraw liboauth docbook-xsl yelp-tools meson git)
  15 optdepends=('libraw: read RAW files'
  16             'exiv2: metadata support'
  17             'brasero: burn discs'
  18             'liboauth: web albums')
  19 _commit=3132c5f25ffe6f22314ab0fbfb08e63ba523afab  # tags/3.12.2^0
  20 source=("git+https://gitlab.gnome.org/GNOME/gthumb.git#commit=$_commit")
  21 sha256sums=('SKIP')
  22
  23 pkgver() {
  24   cd gthumb
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd gthumb
  30
  31   # Fix build with libraw 0.21
  32   git cherry-pick -n da0d3f22a5c3a141211d943e7d963d14090011ec
  33 }
  34
  35 build() {
  36   arch-meson gthumb build
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: