libgnomekbd/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libgnomekbd
   5 pkgver=3.28.1
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="Keyboard management library"
   9 url="https://gitlab.gnome.org/GNOME/libgnomekbd"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(libxklavier gtk3 dconf)
  13 makedepends=(gobject-introspection git meson)
  14 provides=(libgnomekbd{,ui}.so)
  15 _commit=1ca55e9f3644eb20ccee1042a7fa4158465f4aef  # tags/3.28.1^0
  16 source=("git+https://gitlab.gnome.org/GNOME/libgnomekbd.git#commit=$_commit"
  17         meson.diff)
  18 sha256sums=('SKIP'
  19             'd41afc90476de55e1281172b538aa764a4697ff487d11660a7b02503c0630430')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28
  29   # Fixes for meson build
  30   git apply -3 ../meson.diff
  31 }
  32
  33 build() {
  34   arch-meson $pkgname build
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   meson test -C build --print-errorlogs
  40 }
  41
  42 package() {
  43   meson install -C build --destdir "$pkgdir"
  44 }
  45
  46 # vim:set sw=2 sts=-1 et: