networkmanager-openvpn/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-openvpn
   5 pkgver=1.10.2
   6 pkgrel=1
   7 pkgdesc="NetworkManager VPN plugin for OpenVPN"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(libnm libsecret openvpn)
  12 makedepends=(libnma libnma-gtk4 python git)
  13 optdepends=('libnma: GUI support (GTK 3)'
  14             'libnma-gtk4: GUI support (GTK 4)')
  15 options=(debug)
  16 _commit=ae9575dd07cc2d2d51ec8d0297823e07017cb6e6  # tags/1.10.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openvpn.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd NetworkManager-openvpn
  22   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd NetworkManager-openvpn
  27   autoreconf -fvi
  28 }
  29
  30 build() {
  31   cd NetworkManager-openvpn
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --libexecdir=/usr/lib --disable-static --with-gtk4
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 package() {
  39   cd NetworkManager-openvpn
  40   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  41   echo 'u nm-openvpn - "NetworkManager OpenVPN"' |
  42     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  43 }
  44
  45 # vim:set sw=2 sts=-1 et: