nspr/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   4
   5 pkgname=nspr
   6 pkgver=4.35
   7 pkgrel=1
   8 pkgdesc="Netscape Portable Runtime"
   9 url="https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSPR"
  10 arch=(x86_64)
  11 license=(MPL GPL)
  12 depends=(glibc sh)
  13 makedepends=(zip mercurial)
  14 _revision=b563bfc16c887c48b038b7b441fcc4e40a126d3b
  15 source=("hg+https://hg.mozilla.org/projects/nspr#revision=$_revision")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd nspr
  20   hg id -t -r. | sed 's/^NSPR_//;s/_RTM$//;s/_/./g'
  21 }
  22
  23 prepare() {
  24   cd nspr
  25 }
  26
  27 build() {
  28   cd nspr
  29   ./configure \
  30       --prefix=/usr \
  31       --libdir=/usr/lib \
  32       --includedir=/usr/include/nspr \
  33       --enable-optimize \
  34       --disable-debug \
  35       --enable-64bit
  36   make ${SOURCE_DATE_EPOCH:+
  37     SH_NOW="${SOURCE_DATE_EPOCH}000000"
  38     SH_DATE="$(date --utc --date="@$SOURCE_DATE_EPOCH" '+%Y-%m-%d %T')"
  39   }
  40 }
  41
  42 package() {
  43   cd nspr
  44   make DESTDIR="$pkgdir" install
  45   ln -s nspr.pc "$pkgdir/usr/lib/pkgconfig/mozilla-nspr.pc"
  46
  47   rm -r "$pkgdir"/usr/include/nspr/md
  48   rm "$pkgdir"/usr/bin/{compile-et.pl,prerr.properties}
  49 }
  50
  51 # vim:set sw=2 et: