python-numpy/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
   4 # Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
   5
   6 pkgname=python-numpy
   7 pkgver=1.24.3
   8 pkgrel=2
   9 pkgdesc="Scientific tools for Python"
  10 arch=('x86_64')
  11 license=('custom')
  12 url="https://www.numpy.org/"
  13 depends=('cblas' 'lapack' 'python')
  14 optdepends=('openblas: faster linear algebra')
  15 makedepends=('python-setuptools' 'gcc-fortran' 'cython')
  16 checkdepends=('python-pytest' 'python-hypothesis')
  17 options=('staticlibs')
  18 source=("https://github.com/numpy/numpy/releases/download/v$pkgver/numpy-$pkgver.tar.gz")
  19 sha512sums=('d4b5841cbe68ee6653f99018e4e0182f2e5519a1cd69c14e0a95aa180f878e6a6786ccf0a7c78bf0d511c53e7535d7144fee428572dec7a4b60b25c8a1c0c9e1')
  20
  21 build() {
  22   cd numpy-$pkgver
  23   python setup.py build
  24 }
  25
  26 check() {
  27   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  28
  29   cd numpy-$pkgver
  30   python setup.py install --root="$PWD/tmp_install" --optimize=1
  31   cd "$PWD/tmp_install"
  32   PATH="$PWD/usr/bin:$PATH" PYTHONPATH="$PWD/$site_packages:$PYTHONPATH" python -c 'import numpy; numpy.test()'
  33 }
  34
  35 package() {
  36   cd numpy-$pkgver
  37   python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  38
  39   install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/python-numpy/
  40 }