qtcreator/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
   3 # Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
   4 # Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
   5 # Contributor: Dan Vratil <progdan@progdansoft.com>
   6 # Contributor: thotypous <matiasΘarchlinux-br·org>
   7 # Contributor: delor <bartekpiech gmail com>
   8
   9 pkgbase=qtcreator
  10 pkgname=(qtcreator qtcreator-devel)
  11 pkgver=10.0.1
  12 _clangver=15.0.7
  13 pkgrel=1
  14 pkgdesc='Lightweight, cross-platform integrated development environment'
  15 arch=(x86_64)
  16 url='https://www.qt.io'
  17 license=(GPL3)
  18 depends=(qt6-tools qt6-svg qt6-quick3d qt6-webengine qt6-serialport qt6-shadertools qt6-5compat
  19          clang=$_clangver clazy yaml-cpp litehtml) # syntax-highlighting
  20 makedepends=(cmake llvm python)
  21 optdepends=('qt6-doc: integrated Qt documentation'
  22             'qt6-examples: welcome page examples'
  23             'gdb: debugger'
  24             'cmake: cmake project support'
  25             'x11-ssh-askpass: ssh support'
  26             'git: git support'
  27             'mercurial: mercurial support'
  28             'bzr: bazaar support'
  29             'valgrind: analyze support'
  30             'perf: performer analyzer'
  31             'mlocate: locator filter')
  32 source=(https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz)
  33 sha256sums=('4161b07dcec0fc8f31529c7db610b717314128da007a2efa85aa9bc33097a163')
  34 options=(docs)
  35
  36 build() {
  37   cmake -B build -S qt-creator-opensource-src-$pkgver \
  38     -DCMAKE_INSTALL_PREFIX=/usr \
  39     -DCMAKE_INSTALL_LIBEXECDIR=lib \
  40     -DWITH_DOCS=ON \
  41     -DBUILD_DEVELOPER_DOCS=ON \
  42     -DBUILD_QBS=OFF \
  43     -DQTC_CLANG_BUILDMODE_MATCH=ON \
  44     -DCLANGTOOLING_LINK_CLANG_DYLIB=ON
  45   cmake --build build
  46   cmake --build build --target docs
  47 }
  48
  49 package_qtcreator() {
  50   DESTDIR="$pkgdir" cmake --install build
  51 # Install docs
  52   cp -r build/share/doc "$pkgdir"/usr/share
  53
  54   install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
  55 }
  56
  57 package_qtcreator-devel() {
  58   pkgdesc+=' (development files)'
  59   depends=(qtcreator)
  60   optdepends=()
  61
  62   DESTDIR="$pkgdir" cmake --install build --component Devel
  63 }