file-roller/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=file-roller
   5 pkgver=43.0
   6 pkgrel=2
   7 pkgdesc="Create and modify archives"
   8 url="https://wiki.gnome.org/Apps/FileRoller"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(
  12   dconf
  13   file
  14   json-glib
  15   libarchive
  16   libhandy
  17   libportal-gtk3
  18   unzip
  19   zip
  20 )
  21 makedepends=(
  22   appstream-glib
  23   git
  24   libnautilus-extension
  25   meson
  26   yelp-tools
  27 )
  28 optdepends=(
  29   'lrzip: lrzip archive support'
  30   'p7zip: 7z, arj, exe and encrypted zip files support'
  31   'squashfs-tools: squashfs image support'
  32   'unace: ACE archive support'
  33   'unrar: better RAR archive support'
  34 )
  35 groups=(gnome-extra)
  36 _commit=6d57d9962efb976aa3036db965f558b96575289c  # tags/43.0^0
  37 source=("git+https://gitlab.gnome.org/GNOME/file-roller.git#commit=$_commit")
  38 b2sums=('SKIP')
  39
  40 pkgver() {
  41   cd $pkgname
  42   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  43 }
  44
  45 prepare() {
  46   cd $pkgname
  47 }
  48
  49 build() {
  50   arch-meson $pkgname build
  51   meson compile -C build
  52 }
  53
  54 check() {
  55   meson test -C build --print-errorlogs
  56 }
  57
  58 package() {
  59   meson install -C build --destdir "$pkgdir"
  60 }
  61
  62 # vim:set sw=2 sts=-1 et: