wireguard-tools/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Contributor: Jason A. Donenfeld <Jason@zx2c4.com>
   3
   4 pkgname=wireguard-tools
   5 pkgver=1.0.20210914
   6 pkgrel=1
   7 pkgdesc='next generation secure network tunnel - tools for configuration'
   8 arch=('x86_64')
   9 url='https://www.wireguard.com/'
  10 license=('GPL')
  11 depends=('bash')
  12 optdepends=('openresolv: for DNS functionality'
  13             'sudo: elevate privileges')
  14 validpgpkeys=('AB9942E6D4A4CFC3412620A749FC7012A5DE03AE') # Jason A. Donenfeld <Jason@zx2c4.com>
  15 source=("https://git.zx2c4.com/${pkgname}/snapshot/${pkgname}-${pkgver}.tar"{.xz,.asc})
  16 sha256sums=('97ff31489217bb265b7ae850d3d0f335ab07d2652ba1feec88b734bc96bd05ac'
  17             'SKIP')
  18
  19 prepare() {
  20         cd ${pkgname}-${pkgver}/
  21
  22         find contrib/ -name '.gitignore' -delete
  23 }
  24
  25 build() {
  26         cd ${pkgname}-${pkgver}/
  27
  28         make -C src/
  29 }
  30
  31 package() {
  32         cd ${pkgname}-${pkgver}/
  33
  34         make -C src/ \
  35                 DESTDIR="${pkgdir}/" \
  36                 WITH_BASHCOMPLETION=yes \
  37                 WITH_WGQUICK=yes \
  38                 WITH_SYSTEMDUNITS=yes \
  39                 install
  40
  41         install -d -m0755 "${pkgdir}"/usr/share/${pkgname}/
  42         cp -r contrib/ "${pkgdir}"/usr/share/${pkgname}/examples/
  43 }